Steven Frady - Creative Full-Stack Developer

#define GLSLIFY 1
//Sol LeWitt Wall Drawing.
//https://massmoca.org/sol-lewitt/
//https://observer.com/2012/10/here-are-the-instructions-for-sol-lewitts-1971-wall-drawing-for-the-school-of-the-mfa-boston/
//https://publicdelivery.org/sol-lewitt-wall-drawings/
//https://illmindofryza1.wordpress.com/2016/08/17/sol-lewitt-wall-painting-118/

uniform float time;
uniform vec2 resolution;

float noise3D(vec3 p){
    return fract(sin(dot(p,vec3(12.9898,78.233,128.852)))*43758.5453)*2.-1.;
}

float simplex3D(vec3 p){
    float f3=1./3.;
    float s=(p.x+p.y+p.z)*f3;
    int i=int(floor(p.x+s));
    int j=int(floor(p.y+s));
    int k=int(floor(p.z+s));
    
    float g3=1./6.;
    float t=float((i+j+k))*g3;
    float x0=float(i)-t;
    float y0=float(j)-t;
    float z0=float(k)-t;
    x0=p.x-x0;
    y0=p.y-y0;
    z0=p.z-z0;
    int i1,j1,k1;
    int i2,j2,k2;
    if(x0>=y0)
    {
        if(y0>=z0){i1=1;j1=0;k1=0;i2=1;j2=1;k2=0;}// X Y Z order
        else if(x0>=z0){i1=1;j1=0;k1=0;i2=1;j2=0;k2=1;}// X Z Y order
        else{i1=0;j1=0;k1=1;i2=1;j2=0;k2=1;}// Z X Z order
    }
    else
    {
        if(y0<z0){i1=0;j1=0;k1=1;i2=0;j2=1;k2=1;}// Z Y X order
        else if(x0<z0){i1=0;j1=1;k1=0;i2=0;j2=1;k2=1;}// Y Z X order
        else{i1=0;j1=1;k1=0;i2=1;j2=1;k2=0;}// Y X Z order
    }
    float x1=x0-float(i1)+g3;
    float y1=y0-float(j1)+g3;
    float z1=z0-float(k1)+g3;
    float x2=x0-float(i2)+2.*g3;
    float y2=y0-float(j2)+2.*g3;
    float z2=z0-float(k2)+2.*g3;
    float x3=x0-1.+3.*g3;
    float y3=y0-1.+3.*g3;
    float z3=z0-1.+3.*g3;
    vec3 ijk0=vec3(i,j,k);
    vec3 ijk1=vec3(i+i1,j+j1,k+k1);
    vec3 ijk2=vec3(i+i2,j+j2,k+k2);
    vec3 ijk3=vec3(i+1,j+1,k+1);
    vec3 gr0=normalize(vec3(noise3D(ijk0),noise3D(ijk0*2.01),noise3D(ijk0*2.02)));
    vec3 gr1=normalize(vec3(noise3D(ijk1),noise3D(ijk1*2.01),noise3D(ijk1*2.02)));
    vec3 gr2=normalize(vec3(noise3D(ijk2),noise3D(ijk2*2.01),noise3D(ijk2*2.02)));
    vec3 gr3=normalize(vec3(noise3D(ijk3),noise3D(ijk3*2.01),noise3D(ijk3*2.02)));
    float n0=0.;
    float n1=0.;
    float n2=0.;
    float n3=0.;
    float t0=.5-x0*x0-y0*y0-z0*z0;
    if(t0>=0.)
    {
        t0*=t0;
        n0=t0*t0*dot(gr0,vec3(x0,y0,z0));
    }
    float t1=.5-x1*x1-y1*y1-z1*z1;
    if(t1>=0.)
    {
        t1*=t1;
        n1=t1*t1*dot(gr1,vec3(x1,y1,z1));
    }
    float t2=.5-x2*x2-y2*y2-z2*z2;
    if(t2>=0.)
    {
        t2*=t2;
        n2=t2*t2*dot(gr2,vec3(x2,y2,z2));
    }
    float t3=.5-x3*x3-y3*y3-z3*z3;
    if(t3>=0.)
    {
        t3*=t3;
        n3=t3*t3*dot(gr3,vec3(x3,y3,z3));
    }
    return 96.*(n0+n1+n2+n3);
}

const float PI=3.14;

const int paletteSize=7;
const vec3[paletteSize]palette=vec3[](
  vec3(.87,.84,.85),//bg
  vec3(.73,.06,.16),
  vec3(.14,.56,.29),
  vec3(.85,.07,.13),
  vec3(.16,.37,.63),
  vec3(.30,.20,.50),
  vec3(.95,.62,.20)
);

//https://www.youtube.com/watch?v=62-pRVZuS5c
float sdBox(in vec2 p,in vec2 b){
  vec2 d=abs(p)-b;
  return length(max(d,0.))+min(max(d.x,d.y),0.);
}

//https://www.shadertoy.com/view/3lVGWt
mat2 rotationMatrix(float angle){
  angle*=PI/180.;
  float s=sin(angle),c=cos(angle);
  return mat2(c,-s,s,c);
}

void main(){
  vec2 uv=gl_FragCoord.xy/resolution.xy;
  vec3 col=palette[0];
  
  vec2 fRes=resolution.yy;
  vec2 fUv=gl_FragCoord.xy/fRes;
  
  float h=floor(fUv.x+time*.1);
  vec2 fhUv=mod(vec2(fUv.x+time*.1,fUv.y),vec2(1.));
  
  vec2 wfUv=fUv;
  wfUv.y+=sin(wfUv.x*3.)*.2;
  wfUv*=rotationMatrix(simplex3D(vec3(h+15.42,5.262,21.262))*360.);
  
  int stripeY=int(floor(wfUv.y*10.+time*.5));
  int stripeX=int(floor(wfUv.x*5.+simplex3D(vec3(float(stripeY)*14.3727+time*.1))));
  
  vec3 b1Col=palette[int(mod(float(stripeY+stripeX),float(paletteSize)-1.)+1.)];
  vec2 b1Uv=(fhUv-vec2(.5))*vec2(2.15,2.25);
  float b1Sd=sdBox(b1Uv,vec2(1.));
  col=mix(col,b1Col,step(b1Sd,0.));
  
  gl_FragColor=vec4(col,1.);
}
View source on GitHub
More shaders